1.  <program> -> <globals_list> <procedure_list>

2.  <globals_list> -> <globals_list> <globals_decl> | EMPTY

3.  <globals_decl> -> <global_var_decl> | <array_decl>

4.  <global_var_decl> -> var <global_var_list> ;

5.  <global_var_list> -> <global_var_list> , ID | ID

6.  <array_decl> -> array <array_list> ;

7.  <array_list> -> <array_list> , <single_array> | <single_array>

8.  <single_array> -> NUMBER ID

9.  <procedure_list> -> <procedure_list> <procedure_decl> | EMPTY

10. <procedure_decl> -> proc ID ( <formal_parameters> ) <locals_list>
                        <statement_list> endproc

11. <formal_parameters> -> <formal_list> | EMPTY

12. <formal_list> -> <formal_list> , ID | ID

13. <locals_list> -> <locals_list> <local_decl> | EMPTY

14. <local_decl> -> var <local_var_list> ;

15. <local_var_list> -> <local_var_list> , ID | ID

16. <statement_list> -> <statement_list> <statement> ; | EMPTY

17. <statement> -> <assignment> | <conditional> | <loop> | <io> |
                   <call> | <return_value>

18. <assignment> -> <variable> = <arithmetic_expression>
               
19. <conditional> -> if <boolean_expression> <statement_list>
                     <else_clause> endif
 
20. <else_clause> -> else <statement_list> | EMPTY

21. <loop> -> <while_loop> | <do_loop>

22. <while_loop> -> while <boolean_expression> <statement_list>
                    endwhile

23. <do_loop> -> do <statement_list> endo while <boolean_expression>

24. <io> -> <read_statement> | <write_statement> | <line_statement>

25. <call> -> ID ( <actual_parameters> )

26. <return_value>-> retval <arithmetic_expression>

27. <actual_parameters> -> <parameter_list> | EMPTY

28. <parameter_list> -> <parameter_list> , <arithmetic_expression>
                        | <arithmetic_expression>

29. <quantity> -> <variable> | NUMBER | <call> | ' CHARACTER '

30. <variable> -> ID | ID [ <arithmetic_expression> ]

31. <read_statement> -> read ( <variable> ) | readstr ( ID )

32. <write_statement> -> write ( <arithmetic_expression> )
                         | writestr ( " STRING " ) | writestr ( ID )

33. <line_statement> -> line

34. <arithmetic_expression> -> <arithmetic_expression> <add_operator>
                               <arithmetic_term> | <arithmetic_term>

35. <arithmetic_term> -> <arithmetic_term> <mult_operator>
                         <arithmetic_factor> | <arithmetic_factor>

36. <arithmetic_factor> -> <quantity> | ( <arithmetic_expression> )

37. <add_operator> -> + | -

38. <mult_operator> -> * | /

39. <boolean_expression> -> <boolean_expression> or <boolean_term>
                            | <boolean_term>

40. <boolean_term> -> <boolean_term> and <boolean_factor>
                      | <boolean_factor>

41. <boolean_factor> -> not <boolean_atom> | <boolean_atom>

42. <boolean_atom> -> ( <arithmetic_expression> <relational_operator>
                      <arithmetic_expression> )
                      | ( <boolean_expression> )

43. <relational_operator> -> = | < | <= | > | >= | #